Delphi官方提供的对于JSON操作的单元是：system.JSON，delphi将JSON元素都定义为对象，注意是对象，既然是对象就需要创建，需要释放。具体如下：

本文演示 Demo 下载：SZHN_JSON.rar

Delphi JSON 常用对象

编号	对象	说明
1	TJSONValue	所有JSON类的祖先，包括以下锁有对象
2	TJSONObject	一个JSON对象，对应一段JSON字符串
3	TJSONPair	代表一个Key-Value的JSON对，包括josnString和jsonValue
4	TJSONString	代表一个字符串的JSON节点
5	TJSONNumber	代表一个数值的JSON节点，可以是整形，也可以是浮点型（日期是浮点型）
6	TJSONBool	代表一个布尔型的JSON节点
7	TJSONArray	代表一个数组型的JSON节点
8	TJSONTrue	表示一个TJSONBool型的值为True对象
9	TJSONFalse	表示一个TJSONBool型的值为False对象

本文JSON样例，下面程序使用字符串名称为JSONStr替代下面JSON字符串：

{
	"name": "张大顺",
	"age": 40,
	"married": true,
	"books": [
		"《Web开发人员参考大全》",
		"《delphi深度学习》"
	],
	"organization": {
		"oname": "大中华科技",
		"oyear": 20
	}
}

1.生成SJON

原生方法：

procedure TForm1.Button4Click(Sender: TObject);
var
  jo : TJSONObject;
begin
  jo := TJSONObject.Create;
  try
    jo.AddPair('name','张大顺');
    jo.AddPair('age',TJSONNumber.Create(40));
    jo.AddPair('married', TJSONBool.Create(True));
    jo.AddPair('books',TJSONArray.Create
      .Add('《Web开发人员参考大全》')
      .Add('《delphi深度学习》'));
    jo.AddPair('organization',TJSONObject.Create
      .AddPair('oname','大中华科技')
      .AddPair('oyear',TJSONNumber.Create(20)));
    Memo2.Text := JSON_Format(jo.ToString);
  finally
    jo.Free;   //切记这里需要释放
  end;
end;

也可以使用通过Helper实现的类似SuperObject的写法，使用这个方法，需要引入单元uSZHN_JSON.pas

procedure TForm1.Button5Click(Sender: TObject);
var
  jo : TJSONObject;
begin
  jo := TJSONObject.Create;
  try
    jo.S['name'] := '张大顺';
    jo.I['age'] := 40;
    jo.B['married'] := True;
    jo.A['books'] := TJSONArray.Create;
    jo.A['books'].Add('《Web开发人员参考大全》').Add('《delphi深度学习》');

    jo.O['organization'] := TJSONObject.Create;
    jo.O['organization'].S['oname'] := '大中华科技';
    jo.O['organization'].I['oyear'] := 20;
    {
    //也可以如下：
    jo.O['organization'] := TJSONObject.Create.AddPair('oname','大中华科技');
    jo.O['organization'].I['oyear'] := 20;
    }
    Memo2.Text := JSON_Format(jo.ToString);
  finally
    jo.Free;  //切记这里需要释放
  end;
end;

2. 解析JSON

procedure TForm1.Button6Click(Sender: TObject);
var
  jo : TJSONObject;
  name : string;
  age : integer;
  married : Boolean;
  bookname : string;
  oname : string;
begin
  jo := TJSONObject.ParseJSONValue(JSONStr) as TJSONObject;
  if jo = nil then
     begin
       //解析失败，不是JSON格式的字符串
       Exit;
     end;
  try
    //获取姓名
    name := jo.S['name'];   //张大顺
    //获取年龄
    age := jo.I['age'];     //40
    married := jo.B['married'];   //true
    bookname := jo.A['books'].Items[0].ToString;  // 《Web开发人员参考大全》

    oname := jo.O['organization'].S['oname'];  // '大中华科技';
    age   := jo.O['organization'].I['oyear'];  // 20;
  finally
    jo.Free;  //切记这里需要释放
  end;
end;

3. 删除JSON项

procedure TForm1.Button7Click(Sender: TObject);
var
  jo : TJSONObject;
  name : string;
  age : integer;
  married : Boolean;
  bookname : string;
  oname : string;
begin
  jo := TJSONObject.ParseJSONValue(JSONStr) as TJSONObject;
  if jo = nil then
     begin
       //解析失败，不是JSON格式的字符串
       Exit;
     end;
  try
    //删除name
    jo.Remove('name');   //直接输入需要删除的项目名，这句没有加free是因为helper里边已经加了
    //也可以使用下面语句，注意一定要加上free，否则会产生内存泄露
    //jo.RemovePair('name').Free;    //这是原生的用法
    //删除数组中项目
    jo.A['books'].Remove(0).free;  //删除数组中的第一项：《Web开发人员参考大全》

    Memo2.Text := JSON_Format( jo.ToString);
  finally
    jo.Free;  //切记这里需要释放
  end;
end;

删除后的结果：

{
  "age": 40,
  "married": true,
  "books": 
  [
    "《delphi深度学习》"
  ],
  "organization":
  {
      "oname": "大中华科技",
      "oyear": 20
  }
}

4. JSON数组操作

样例代码一、

procedure TForm1.Button8Click(Sender: TObject);
var
  jo : TJSONObject;
  ja : TJSONArray;
begin
  jo := TJSONObject.ParseJSONValue(JSONStr) as TJSONObject;
  if jo = nil then   //如果jo不是JSON对象，直接退出
     exit;
  ja := TJSONArray.Create;
  try
    ja.Add('增加一个字符串');
    ja.Add(1024);    //增加数字1024
    ja.Add(False);    //增加布尔值 False
    ja.Add(TJSONObject.Create.AddPair('street','st 208'));  //直接增加一个对象
    jo.AddPair('数组',ja);
    Memo2.Text := JSON_Format(jo.ToString);
  finally
    jo.Free;
    //注意 ja 不需要释放，因为在释放 jo的时候系统会自动释放
  end;

end;

执行后结果：

{
  "name": "张大顺",
  "age": 40,
  "married": true,
  "books": 
  [
    "《Web开发人员参考大全》",
    "《delphi深度学习》"
  ],
  "organization":
  {
      "oname": "大中华科技",
      "oyear": 20
  },
  "数组": 
  [
    "增加一个字符串",
    1024,
    false,
    {
        "street": "st 208"
    }
  ]
}

样例代码二、

procedure TForm1.Button9Click(Sender: TObject);
var
  jo : TJSONObject;
  ja : TJSONArray;
  i : Byte;
begin
  ja := TJSONArray.Create; //创建数组对象
  try
    for i := 1 to 3 do
       begin
        jo := TJSONObject.Create;   //创建数组元素，是JSON对象
        jo.S['name'] := 'sensor' + i.ToString;
        jo.I['index']:= i;
        ja.Add(jo);       //将数组元素增加到数组中
       end;
    Memo2.Text := JSON_Fromat_Array(ja);
  finally
    ja.Free;  //注意 jo 不需要释放，因为在释放 ja的时候系统会自动释放
  end;
end;

执行结果：

[
  {
      "name": "sensor1",
      "index": 1
  },
  {
      "name": "sensor2",
      "index": 2
  },
  {
      "name": "sensor3",
      "index": 3
  }
],

总结：

1. 作为对象内嵌元素的对象是不需要释放的，只需要释放最外对象即可；
2. 如果删除元素，不管是删除数组中的元素还是删除JSON对象，都需要Free，否则会产生内存泄漏（测试5万次就会有明显累积）；
3. 使用TJSONObject的助手单元uSZHN_JSON.pas，操作JSON会书写更加简便；